ceps
Prev | Orchestra Opcodes and Operators | Next

## ceps

ceps — Calculate the cepstrum of an array input, optionally filtering coefficients.

## Description

## Syntax

    keps[] ceps kmags[][, icoefs]

## Initialization

icoefs -- the number of retained coefficients in the cepstrum output. By default, no coefficients are filtered.

## Performance

keps[] -- the cepstrum output, an array of size N+1, where N is a power of two.

kmags[] -- an input array containing N+1 magnitudes.

## Examples

Here is an example of the use of the ceps opcode. It uses the file ceps.csd.

Example 126. Example of the ceps opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    </CsOptions>
    <CsInstruments>

    instr 1

    a1 diskin "fox.wav",1,0,1
    k1 randh  80, 2.5
    a2 vco2  1, 220+k1
    kfsig[] init 1026
    fsig pvsanal a1,1024,256,1024,1
    fsig2 pvsanal a2,1024,256,1024,1
    kf pvs2tab kfsig,fsig
    keps[] ceps c2r(kfsig),30
    kenv[] cepsinv keps
    fenv tab2pvs r2c(kenv)
    fvoc pvsfilter fsig2, fenv, 1
    asig pvsynth fvoc

        out asig
    endin

    </CsInstruments>
    <CsScore>
    i1 0 60
    </CsScore>
    </CsoundSynthesizer>

## See Also

pvsanal, pvsynth, pvsadsyn, pvspitch

## Credits

Author: Victor Lazzarini
2014

Prev | Up | Next
centroid | Home | cepsinv